关于太吾绘卷的一些核心功能实现方法

梁咸蛋

最近一直在玩太吾绘卷,玩的时候就在思考游戏的具体实现过程

Zhangxuetu

数据量很大，不好做。事件也跟每次移动挂钩，tilemap做地图，每个图块都有特定的数据，每次移动都会更新数据信息，更新内容根据设计的逻辑更新，然后物品，战斗，建筑等等，太多了…

梁咸蛋

Zhangxuetu 我也是无聊想尝试一下哈哈哈…

梁咸蛋

地图:

可以用godot的tilemap实现与一般tilemap的区别就是将类型从square格式改为isometric格式

从kenney下一个免费的素材

注意的点就这几个

最后是效果图:

看着有内味了是不是但是还有很多工作未做

比如每个图块都有对应的资源信息,如图

其中的数据结构应该怎么做数据的持久化与玩家的交互都要考虑目前正在构思中欢迎大佬指点迷津

wayrboy

梁咸蛋持久化还得看官方存档,直接把控件数据保存进去,读取的时候kill掉原始的控件,然后再加载自己的配置,这个持久化功能牛逼.

wayrboy

梁咸蛋持久化量大,但是应该不繁琐,每个块都有一个save功能,保存的时候需要把所有的块信息保存出去.

梁咸蛋

经过了一天的思考大概有了一点想法

首先我将tilemap类型改成了custom(因为isometric每个图块距离有点太近了还是搞成自定义后距离可以调整)

将自定义编号改成如图配置就和isometric类型一样了

然后为了更好的看效果我们添加一个摄像机注意勾选其中的锚点模式与启用属性

顺便开始添加脚本并定义一些属性

为什么用内部类来存储数据而不是字典

我思考的是以后会涉及到图块的数据计算可以在内部类自定义一些方法直接调用

而字典做不到这个效果

之后就是我们熟悉的ready函数

添加一个5*5的地图来测试一下

其中的每个地图的属性都是随机的 type对应tilemap的图块索引

我们来看看效果吧

很好但是我们的摄像机还不能移动我们只能看到一半地图

我们通过监听鼠标滚轮与鼠标中键来缩放摄像机与拖动摄像机

我们来看看效果:

2022-01-04-22-32-56-921.mp4

3MB

感觉还行

接下来我们继续添加鼠标左键监听

用鼠标左键的点击来获取每一个图块的数据

最后来测试一下:

成功后面我将附上代码与demo文件

梁咸蛋

代码与文件如下需要自取

5eab50cc-15e8-43b2-92c0-47b529aad491.zip

1MB

extends Node2D

#摄像机

onready var camera = $Camera2D

#缩放倍数

var zoom_num = 1

#鼠标是否点击中键

var is_mouse_mid_click:bool

#鼠标中键点击初始位置

var mouse_click_pos:Vector2

#相机当前位置

var camera_now_pos:Vector2

#瓦片地图

onready var tilemap = $TileMap

#创建一个数组用来存储地图数据

onready var map_data = []

#内部类 存储每个图块数据

class map_block:

	#这里只搞两个简单的资源用于演示 其他的资源同理

	#地块类型

	var type:int

	#木材

	var wood:int

	#食物

	var food:int

	func sout():

		print("[MapBlock] type:%s food:%s wood:%s"%[type,food,wood])

func _ready():

	#设置摄像机视野缩放比例 此比例会用在获取tilemap坐标中

	camera.zoom = Vector2(zoom_num,zoom_num)

	#获取随机数对象

	var random = RandomNumberGenerator.new()

	#随机生成一个5*5的地图

	for x in 5:

		#一维数组

		var od_arr = []

		for y in 5:

			#为生成器设置一个基于时间的种子。

			random.randomize()

			#实例化图块对象

			var single_block = map_block.new()

			#type对应tilemap图块索引

			single_block.type = random.randi_range(0, 3)

			single_block.wood = random.randi_range(0, 100)

			single_block.food = random.randi_range(0, 100)

			#每个图块添加进一维数组

			od_arr.append(single_block)

		#将一维数组放入map_data中

		map_data.append(od_arr)

	#现在将map_data转换为tilemap

	for x in map_data.size():

		for y in map_data[x].size():

			tilemap.set_cell(x,y,map_data[x][y].type)

func _input(event):

	#监听鼠标

	if event is InputEventMouseButton:

		match event.button_index:

			#鼠标滚轮向上

			BUTTON_WHEEL_UP:

				if zoom_num < 0.5:

					return

				zoom_num -= 0.1

			#鼠标滚轮向下

			BUTTON_WHEEL_DOWN:

				if zoom_num > 3.1:

					return

				zoom_num += 0.1

			#鼠标中键 按住拖动地图

			BUTTON_MIDDLE:

				#中键按下记录起始点

				if event.is_pressed():

					is_mouse_mid_click = true

					mouse_click_pos = event.position

					camera_now_pos = camera.position

				#中键取消 计算偏移量

				else:

					is_mouse_mid_click = false

					mouse_click_pos = Vector2.ZERO

			#鼠标左键 展示地块信息

			BUTTON_LEFT:

				if event.is_pressed():

					var pos = event.position

					#pos需要计算摄影机的缩放补偿与拖拽偏移量 才能正确的获得tilemap坐标

					pos = pos*zoom_num+camera.position

					var map_position = $TileMap.world_to_map(pos)

					if $TileMap.get_cellv(map_position) == -1:

						return

					get_block_info(map_position)

	#这个放外边是为了点击中键的时候及时刷新相机位置

	if is_mouse_mid_click:

		var offset = mouse_click_pos - event.position

		camera.position = camera_now_pos + offset

#获取tilemap中图块的数据

func get_block_info(vec:Vector2):

	map_data[vec.x][vec.y].sout()

func _process(delta):

	#添加一个镜头缩放缓动效果

	camera.zoom = lerp(camera.zoom,Vector2(zoom_num,zoom_num),8*delta)

梁咸蛋

但这还不算完还有很多坑需要解决

比如图块应该还有个包涵此图块中所有npc的数组(包括活着的npc 还有死去的npc墓碑)

还有城镇图块的产业视图

还有随季节在地图上随机产生在每个图块上的游戏事件(如抓蛐蛐强盗窝恶改以及剑冢)

这些我都还在想怎么弄…欢迎大神指点

Zhangxuetu

不错哦！很强

梁咸蛋

目前做的一个简单的演示demo 还有很多地方需要改进…

梁咸蛋

梁咸蛋上下左右移动按住鼠标中键拖动镜头

qwqiqoq

感觉camera做成fixed topleft之后，缩放操作不自然，于是我还是用了默认的drag center，在_input中左键响应代码中坐标变换改为：

pos = (pos - screen_center)* zoom_num + camera.position

其中screen_center初始化为窗口中心坐标

ASC_8384

跪求大佬重新分享一下新代码